Не могу перекрыть базовый метод [Delphi] - Public forum of MSU united student networks

исходники подменять нельзя, а вот переопределять классы - влегкую!
вот вам пример:
code:unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

const
  TMWM__SpecialInvalidate = WM_USER + 1111;

type
  TEdit = class(StdCtrls.TEdit)
  private
    FClarity  : Boolean;
    procedure SetClarity(const Value: Boolean);
    { Private declarations }
  protected
    { Protected declarations }
    procedure CMEraseBkgnd    (var Message: TWMEraseBkgnd);    Message WM_ERASEBKGND;
    procedure WMSetText        (var Message: TWMSetText);
    procedure SpecialInvalidate(var Message: TMessage);        message TMWM__SpecialInvalidate;
    procedure CNCTLCOLOREDIT  (var Message: TWMCTLCOLOREDIT);  message CN_CTLCOLOREDIT;
    procedure WMKeyDown        (var Message: TWMKeyDown);      message WM_KEYDOWN;
    procedure WMKillFocus      (Var Message: TWMKillFocus);    Message WM_KillFocus;
    procedure WMLButtonDown    (Var Message: TWMLButtonDown);  Message WM_LButtonDown;
    procedure WMMove          (Var Message: TWMLButtonDown);  Message WM_Move;
    procedure WMMouseMove      (Var Message: TWMMouseMove);    Message WM_MouseMove;
    procedure CreateParams(var Params: TCreateParams); override;
    procedure CreateWnd; override;
  public
    { Public declarations }
    constructor Create(AOwner: TComponent); override;
    procedure  Invalidate; override;
    property    Clarity:Boolean read FClarity write SetClarity default True;
  end;

  TForm1 = class(TForm)
    Edit1: TEdit;
  private
    { Private declarations }
  public
    { Public declarations }
  end;


var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TEdit }

procedure TEdit.CMEraseBkgnd(var Message: TWMEraseBkgnd);
begin
  if Clarity then
    Message.Result := 1;
end;

procedure TEdit.CNCTLCOLOREDIT(var Message: TWMCTLCOLOREDIT);
begin
  if Clarity then
  with Message do
    begin
      SetBkMode(ChildDC,Windows.TRANSPARENT);
      Result:=GetStockObject(HOLLOW_BRUSH);
    end
  else inherited;
end;

constructor TEdit.Create(AOwner: TComponent);
begin
  inherited create(AOwner);
  BorderStyle := bsNone;
  BevelKind := bkNone;
  Clarity:=true;
end;

procedure TEdit.CreateParams(var Params: TCreateParams);
begin
  inherited CreateParams(Params);
  if (CsDesigning in ComponentState) then exit;
  with Params do
  begin
    ExStyle:=ExStyle or WS_EX_TRANSPARENT;
  end;
end;

procedure TEdit.CreateWnd;
begin
  inherited CreateWnd;
  if Clarity then
  begin
    SetWindowLong(Parent.Handle, GWL_STYLE,
      GetWindowLong(Parent.Handle, GWL_STYLE) and not WS_CLIPCHILDREN);
  end;
end;

procedure TEdit.Invalidate;
begin
  if Clarity then PostMessage(Handle,TMWM__SpecialInvalidate,0,0)
    else inherited;
end;

procedure TEdit.SetClarity(const Value: Boolean);
begin
  FClarity := Value;
end;

procedure TEdit.SpecialInvalidate(var Message: TMessage);
var
  rect:TRect;
begin
  if Parent<>nil then
  begin
    rect:=ClientRect;
    rect.TopLeft:=Parent.ScreenToClient(ClientToScreen(rect.TopLeft));
    rect.BottomRight:=Parent.ScreenToClient(ClientToScreen(rect.BottomRight));
    InvalidateRect(Parent.Handle,@rect,true);
    RedrawWindow(Handle,nil,0,RDW_FRAME+RDW_INVALIDATE)
  end;
end;

procedure TEdit.WMKeyDown(var Message: TWMKeyDown);
begin
  SendMessage(Handle,TMWM__SpecialInvalidate,0,0);
  inherited;
  PostMessage(Handle,TMWM__SpecialInvalidate,0,0);
end;

procedure TEdit.WMKillFocus(var Message: TWMKillFocus);
begin
  inherited;
  if not (csDesigning in ComponentState) then
    PostMessage(Handle,TMWM__SpecialInvalidate,0,0)
end;

procedure TEdit.WMLButtonDown(var Message: TWMLButtonDown);
begin
  inherited;
  if not (csDesigning in ComponentState) then
    PostMessage(Handle,TMWM__SpecialInvalidate,0,0);
end;

procedure TEdit.WMMouseMove(var Message: TWMMouseMove);
begin
  inherited;
  if not (csDesigning in ComponentState) then
    PostMessage(Handle,TMWM__SpecialInvalidate,0,0);
end;

procedure TEdit.WMMove(var Message: TWMLButtonDown);
begin
  inherited;
  //if not (csDesigning in ComponentState) then
    PostMessage(Handle,TMWM__SpecialInvalidate,0,0);
end;

procedure TEdit.WMSetText(var Message: TWMSetText);
begin
  inherited;
  if not (csDesigning in ComponentState) then
    PostMessage(Handle,TMWM__SpecialInvalidate,0,0);
end;

end.
Но гораздо правильнее запихать его в пэкадж, и присвоить какое-нибудь собственное имя.