Интересные ссылки, HOWTO, tips и т.д. постим здесь - Public forum of MSU united student networks

Как, имея трек прошлогодней, в общем-то, прогулки в формате gps, соорудить адов скрипт, чтоб дико подсчитать, какие были параметры движения с 9:00 до 11:00 по Гринвичу, например?

code:$ gpsbabel -i gpx -f molochnoje.gpx -x track,speed,merge,start=2009022309,stop=2009022311 -o gpx -F - | gawk '
BEGIN {
        FS = "[><]"
        oldtm = 0
        odo = 0
        max = 0
        fulltime = 0
        firsttime = 1
        deltat = 0
}
/time/ {
        if(firsttime) {
                firsttime = 0;next
        }
        sub("T","\\ ",$3)
        sub("Z","",$3)
        getTime = "date -ud " $3 " +%s"
        getTime | getline tm
        close(getTime)
        if(oldtm > 0) deltat = tm - oldtm
        oldtm = tm
        fulltime += deltat
}
/speed/ {
        if(max < $3) max = $3
        odo += $3 * deltat
}
END {
        printf("Tim: %f\nMax: %f kmph\nOdo: %f km\nAvg: %f kmph\n", fulltime, max * 3.6, odo / 1000, odo * 3.6 / fulltime)
}'
Tim: 7185.000000
Max: 31.420217 kmph
Odo: 12.481229 km
Avg: 6.253643 kmph

Это если имелся gpx, в котором была хотя бы такая информация на каждую точку трека:

code:<trkpt lat="59.246628284" lon="39.833421707">
  <ele>110.208252</ele>
<time>2009-02-23T11:54:46Z</time>
</trkpt>

Следует решительнее обратить внимание на параметры фильтра для гпсбабеля: start и stop - ограничения по времени, merge - склеить все треки в один; speed - означает, что для каждой точки трека будет дополнительно синтезировано поле "<speed></speed>". gpsbabel, душка, размещает его, как и поле <time> на отдельной строке, что упрощает ~~быдлопарсинг~~ обработку статданных на awk.
То что идет после пайпа, уже не столь интересно, не считая такого момента:

code:/time/ {
        if(firsttime) {
                firsttime = 0;next
        }

Обусловлен он тем, что gpsbabel поместит в начало результирующего gpx таймстамп, когда этот gpx создан. В моем случае это через год с лишним после создания трека, что подарило немало чудесных минут дебага. :val:

Ну и да, наконец узнал, как в авк закрываются пайпы команд.

Начать обсуждение